製品

ソリューション

コネクタ

サポート

価格

企業情報

お役立ち情報

ブログ

検索お問い合わせ

製品をチェック

XML ODBC Driver の30日間無償トライアルをダウンロード

30日間の無償トライアルへ

製品の詳細

XML ODBC Driver 相談したい

XML ODBC Driver は、ODBC 接続をサポートする様々なアプリケーションからXML データストアへの接続を実現するパワフルなツールです.

標準データベースにアクセスするときと同感覚でXML データにアクセスし、標準ODBC Driver インターフェースを通じて読み出し、書き込み、更新が可能に。

FoxPro でXML データを操作

XML をFoxPro データベースにロードします。この記事では、完全なコードとプロセスのウォークスルーを提供します。

古川えりか
コンテンツスペシャリスト
最終更新日：2022-06-26

CData

こんにちは！ドライバー周りのヘルプドキュメントを担当している古川です。

CData ODBC Driver for XML は、ODBC スタンダードを使用してXML にアクセスすることを可能にします。また、CData ODBC Driver for XML を使用して、XML をFoxPro プロジェクトに統合することも可能です。以下のステップは、含まれているコードサンプルのウォークスルーを提供します。このコードでは、XML データをFoxPro データベースのテーブルに保存します。

CData ODBC ドライバとは？

CData ODBC ドライバは、以下のような特徴を持ったリアルタイムデータ連携ソリューションです。

XML をはじめとする、CRM、MA、会計ツールなど多様なカテゴリの270種類以上のSaaS / オンプレミスデータソースに対応
多様なアプリケーション、ツールにXML データを連携
ノーコードでの手軽な接続設定
標準 SQL での柔軟なデータ読み込み・書き込み

CData ODBC ドライバでは、1.データソースとしてXML の接続を設定、2.FoxPro 側でODBC Driver との接続を設定、という2つのステップだけでデータソースに接続できます。以下に具体的な設定手順を説明します。

CData ODBC ドライバのインストールとXML への接続設定

まずは、本記事右側のサイドバーからXML ODBC Driver の無償トライアルをダウンロード・インストールしてください。30日間無償で、製品版の全機能が使用できます。

未指定の場合は、初めにODBC DSN（data source name）で接続プロパティを指定します。ドライバーのインストールの最後にアドミニストレーターが開きます。Microsoft ODBC Data Source Administrator を使用して、ODBC DSN を作成および構成できます。

NOTE:［Map To WVarchar］接続プロパティをFALSE に設定します。(FoxPro はODBC W API を使用し、値タイプのWCHAR を返します。)

データソースを認証するには、データプロバイダーのドキュメント内の「はじめに」セクションをご覧ください。データプロバイダーはXML API を双方向データベーステーブルとしてモデル化し、XML ファイルをread-only ビュー（ローカルファイル、人気のクラウドサービスに格納されたファイル、およびFTP サーバー）としてモデル化します。 HTTP Basic、Digest、NTLM、OAuth、およびFTP を含む主な認証スキームはサポートされています。認証のガイドについては、データプロバイダーのドキュメント内の「はじめに」セクションをご覧ください。

URI と認証値を設定した後で、DataModel を設定することでデータの構造によりよくマッチするようデータの抽象化を調整できます。

DataModel プロパティはデータがどのようにテーブルとして抽象化されるかを制御するプロパティであり、次の基本的な設定を調整します。

Document（デフォルト）：XML データのトップレベルのドキュメントビューをモデル化します。データプロバイダーは入れ子化した要素をデータの集約値として返します。
FlattenedDocuments：入れ子化したドキュメントとその親を結合して単一のテーブルに入力します。
Relational：個別の関連テーブルを階層化されたデータから返します。テーブルは主キーと、親ドキュメントにリンクする外部キーを含みます。

リレーショナルな抽象化の設定についての詳細は、「XML データのモデリング」セクションを参照してください。次の例で使用されているサンプルデータも存在します。このデータには、人名、その人たちが所有する車、車に施されたさまざまなメンテナンスに関する情報が含まれます。

接続して転送

開始するには、コードサンプルを新しいプロジェクトに追加します。以下のコマンドを実行することで、テーブルをすべて表示することなく保存できます。

DO C:\Temp\sqldump.prg WITH "CData XML Source", "TESTDB", .f.

以下は、プログラムが従うプロセスです。

新しいFoxPro データベースを作成します。
以下の行でXML への接続を開きます。
m.hSQLconnection = SQLCONNECT(m.cODBCDSN)
接続が成功したら、SQLTABLES 関数を使用してテーブルのリストを取得できるようになります。以下のコードは、テーブルのリストをsys_tables.dbf に保存します。
WAIT WINDOW "Fetching tables for data source '" + m.cODBCDSN + "'..."NOWAIT NOCLEAR m.nSQLTABLES = SQLTABLES(m.hSQLconnection) IF lUseDistinctConnections WAIT WINDOW "Closing ODBC Connection for data source '" + m.cODBCDSN + "'..."NOWAIT NOCLEAR SQLDISCONNECT(m.hSQLconnection) m.hSQLconnection = 0 * SQLCONNECT needs to be called again ENDIF IF m.nSQLTABLES > 0 * create local table containing list of tables in db COPY TO (m.cImportData + "sys_tables") USE * convert each table to DBF USE (m.cImportData + "sys_tables") ALTER TABLE DBF("sys_tables") ; ADD COLUMN records i ; ADD COLUMN dbfname m
各テーブルをスキャンしてDBF ファイルに保存します。関数ODBCtoDBF は、テーブルをDBF ファイルに格納し、lBrowse パラメータがtrue に設定されている場合はグリッドを開きます。 FUNCTION ODBCtoDBF (cTableName as String, cTableType as String, lBrowse as Logical, lhSQLConnection as Integer) WAIT WINDOW ; "Converting " + m.cTableType + ' "' + m.cTableName + '" to DBF...' ; NOWAIT NOCLEAR ACTIVATE SCREEN * strip characters incompatible with FoxPro out of the name of the DBF file m.cTableAlias = "" m.nTableNameLen = LEN(m.cTableName) m.nTableNameStart = 1 FOR m.nTableNameStart = 1 TO m.nTableNameLen m.cCharacter = SUBSTR(m.cTableName, m.nTableNameStart, 1) IF !ISALPHA(m.cCharacter) .and. (m.nTableNameStart = 1 .or. !ISDIGIT(m.cCharacter)) m.cTableAlias = m.cTableAlias + "_" ELSE m.cTableAlias = m.cTableAlias + m.cCharacter ENDIF ENDFOR m.cFromTable = m.cTableName m.cTempViewAlias = m.cTableType + "_" + m.cTableAlias LOCAL loException as Exception LOCAL lnResultSets TRY * run query m.lnResultSets = SQLEXEC(m.lhSQLConnection, ; "SELECT * FROM " + m.cFromTable, ; m.cTempViewAlias, ; aSQLResult) IF m.lnResultSets#1 SET STEP ON ENDIF ACTIVATE SCREEN CATCH TO m.loException ACTIVATE SCREEN ?"Error opening " + m.cTempViewAlias + ":" ? m.loException.Message ? m.loException.Details ENDTRY IF !USED(m.cTempViewAlias) RETURN ENDIF * copy records from view cursor to disk SELECT * FROM (m.cTempViewAlias) ; INTO TABLE (m.cImportData + m.cTableAlias) IF USED(m.cTableAlias) ACTIVATE SCREEN FLUSH && flush the buffer to write the data to disk IF m.lBrowse * pop the table up on screen SELECT (m.cTableAlias) BROWSE NORMAL NOMODIFY NOWAIT ACTIVATE SCREEN ELSE * close on-disk table for now USE IN (m.cTableAlias) ACTIVATE SCREEN ENDIF ENDIF IF USED(m.cTempViewAlias) USE IN &cTempViewAlias && close SQL view ACTIVATE SCREEN ENDIF WAIT CLEAR ENDFUNC
これで、XML のテーブルをDBF ファイルとして保存できます。

以下は、FoxPro 9 構文の完全なコードです。


PARAMETERS cODBCDSN, cDatabaseName, lBrowseAfterConvert

*	cODBCDSN				The ODBC data source name, used for the name of the folder where the DBF tables are stored.
*	cDatabaseName			The name of the FoxPro database to use.This database is created if it does not exist.The default is DATABASE_NAME.
*								
*	lBrowseAfterConvert		If ".t." display each table with the BROWSE command after importing it.If ".f." close each table before moving on to the next one.

#define		ODBC_DATASOURCE		"DataSourceName"
#define		DATABASE_NAME		"odbcdata"

m.m_tpath = ".\"                && root directory for data

ON ERROR
SET SAFETY OFF

IF VARTYPE(m.cODBCDSN)#"C" .or.EMPTY(m.cODBCDSN)
  m.cODBCDSN = ODBC_DATASOURCE
ENDIF
IF VARTYPE(m.cDatabaseName)#"C" .or.EMPTY(m.cDatabaseName)
  m.cDatabaseName = DATABASE_NAME
ENDIF

m.cImportData = m.cODBCDSN + "\"

CLOSE TABLES ALL
CLOSE DATABASES ALL

IF !DIRECTORY(m.cImportData)
	MKDIR (m.cImportData)
ENDIF

CREATE DATABASE (m.cDatabaseName)
CREATE CONNECTION (m.cDatabaseName) DATASOURCE (m.cODBCDSN) DATABASE (m.cDatabaseName)

WAIT WINDOW "Opening ODBC Connection for data source '" + m.cODBCDSN + "'..."NOWAIT NOCLEAR
m.hSQLconnection = SQLCONNECT(m.cODBCDSN)

IF m.hSQLconnection > 0
  * Connection successful; get list of tables
  WAIT WINDOW "Fetching tables for data source '" + m.cODBCDSN + "'..."NOWAIT NOCLEAR
  m.nSQLTABLES = SQLTABLES(m.hSQLconnection)

  IF m.nSQLTABLES > 0
    * Create local table containing list of tables in db
    COPY TO (m.cImportData + "sys_tables")
    USE

    * Convert each table to DBF
    USE (m.cImportData + "sys_tables")
    ALTER TABLE DBF("sys_tables") ;
    ADD COLUMN records	i ;
    ADD COLUMN dbfname	m

    SCAN	
    m.cCurrentTable	= TRIM(sys_tables.table_name)
    m.cCurrentTableType	= TRIM(sys_tables.table_type) && Valid values are "SYSTEMTABLE", "TABLE", and "VIEW".
    IF m.cCurrentTableType = "TABLE" or m.cCurrentTableType = "VIEW"

      ODBCtoDBF(m.cCurrentTable, m.cCurrentTableType, m.lBrowseAfterConvert, m.hSQLConnection)
    ELSE
      ACTIVATE SCREEN
      ?"ERROR:", m.cCurrentTable, "Couldn't open ODBC connection."
      =MESSAGEBOX("couldn't open data source " + m.cODBCDSN + " for table " + m.cCurrentTable + ".")
    ENDIF

    ENDSCAN
    BROWSE NORMAL NOWAIT

  ELSE
    =MESSAGEBOX("No tables found in data source " + m.cODBCDSN + ".")
    SET STEP ON
  ENDIF
  
  SQLDISCONNECT(m.hSQLconnection)
  
ELSE
  =MESSAGEBOX("Could not open data source " + m.cODBCDSN + ".")
  SET STEP ON
ENDIF

FUNCTION ODBCtoDBF (cTableName as String, cTableType as String, lBrowse as Logical, lhSQLConnection as Integer)

  WAIT WINDOW ;
  "Converting " + m.cTableType + ' "' + m.cTableName + '" to DBF...' ;
  NOWAIT NOCLEAR

  ACTIVATE SCREEN

  * Strip characters incompatible with FoxPro out of the name of the DBF file
  m.cTableAlias		= ""
  m.nTableNameLen		= LEN(m.cTableName)
  m.nTableNameStart	= 1
  
  FOR m.nTableNameStart = 1 TO m.nTableNameLen
    m.cCharacter = SUBSTR(m.cTableName, m.nTableNameStart, 1)	
    IF !ISALPHA(m.cCharacter) .and. (m.nTableNameStart = 1 .or. !ISDIGIT(m.cCharacter))
      m.cTableAlias = m.cTableAlias + "_"
    ELSE
      m.cTableAlias = m.cTableAlias + m.cCharacter
    ENDIF
  ENDFOR

  m.cFromTable = m.cTableName
  m.cTempViewAlias	= m.cTableType + "_" + m.cTableAlias

  LOCAL loException as Exception
  LOCAL lnResultSets
  
  TRY
    * Run query
    m.lnResultSets = SQLEXEC(m.lhSQLConnection, ;
      "SELECT * FROM " + m.cFromTable, ;
      m.cTempViewAlias, ;
      aSQLResult)
	  
    IF m.lnResultSets#1
      SET STEP ON
    ENDIF
	
    ACTIVATE SCREEN

  CATCH TO m.loException
    ACTIVATE SCREEN
    ?"Error opening " + m.cTempViewAlias + ":"
    ? m.loException.Message
    ? m.loException.Details
  ENDTRY

  IF !USED(m.cTempViewAlias)
    RETURN
  ENDIF

  * Copy records from view cursor to disk
  SELECT * FROM (m.cTempViewAlias) ;
    INTO TABLE (m.cImportData + m.cTableAlias)

  IF USED(m.cTableAlias)

    ACTIVATE SCREEN

    FLUSH	&& Flush the buffer to write the data to disk

    IF m.lBrowse
      * Display the table on screen
      SELECT (m.cTableAlias)
      BROWSE NORMAL NOMODIFY NOWAIT
      ACTIVATE SCREEN
    ELSE
      * Close on-disk table
      USE IN (m.cTableAlias)
      ACTIVATE SCREEN
    ENDIF
  ENDIF

  IF USED(m.cTempViewAlias)
    USE IN &cTempViewAlias && Close SQL view
    ACTIVATE SCREEN
  ENDIF

  WAIT CLEAR

ENDFUNC

おわりに

このようにCData ODBC ドライバと併用することで、270を超えるSaaS、NoSQL データをコーディングなしで扱うことができます。30日の無償評価版が利用できますので、ぜひ自社で使っているクラウドサービスやNoSQL と合わせて活用してみてください。

CData ODBC ドライバは日本のユーザー向けに、UI の日本語化、ドキュメントの日本語化、日本語でのテクニカルサポートを提供しています。

トライアル・お問い合わせ

30日間無償トライアルで、CData のリアルタイムデータ連携をフルにお試しいただけます。記事や製品についてのご質問があればお気軽にお問い合わせください。

無償トライアルへ

お問い合わせ

CData Software は、データアクセスおよびデータ接続ソリューションのリーディングプロバイダーです。CData の標準コネクタはあらゆるツール・ミドルウェアからのSaaS やDB データの連携を簡単にします。

お問い合わせ

製品概要

データコネクタ

ETL/ ELT ソリューション

クラウド&API 接続

OEM & カスタムドライバー開発

お問い合わせ先

製品を知る

データ分析 & BI

企業情報

ニュース & 事例